当前位置：首页 > news >正文

uniapp报毒

news 来源：原创 2025/6/3 18:22:31

uniapp打包的apk，装机量多了就开始报毒，尝试了多种解决办法都无解！！

去某宝，解决一次50-100不等，并且没有售后，掉了重新做包，很是无解，包月价格更是离谱。

为此自行测试找到了合适的办法。

一、上架

二、改包

修改uniapp的包名，重新生成证书，为此做了一个一件生成证书的脚本，配合开发者中心【https://dev.dcloud.net.cn/】生成新的包名即可

@echo off
rem 设置 JDK 的 bin 目录
set JDK_BIN_DIR=C:\Program Files\Java\jdk-17\bin
rem 设置证书生成目录
set KEYSTORE_DIR=d:\keystore
rem 设置默认密码
set PASSWORD=adminadmin
rem 设置单位信息
set ORGANIZATION="北京xx科技有限公司"
set LOCATION="北京"
set COUNTRY="CN"

rem 检查证书生成目录是否存在，如果不存在则创建
if not exist "%KEYSTORE_DIR%" (
    mkdir "%KEYSTORE_DIR%"
    if %errorlevel% neq 0 (
        echo 创建证书生成目录 %KEYSTORE_DIR% 时出错！
        pause
        exit /b 1
    )
)

rem 提示用户输入证书别名
set /p ALIAS=请输入证书别名: 

rem 生成 Keystore 文件
"%JDK_BIN_DIR%\keytool.exe" -genkeypair -alias %ALIAS% -keyalg RSA -keysize 2048 -storetype PKCS12 -keystore "%KEYSTORE_DIR%\%ALIAS%.keystore" -storepass %PASSWORD% -keypass %PASSWORD% -dname "CN=%ALIAS%, OU=%ORGANIZATION%, O=%ORGANIZATION%, L=%LOCATION%, S=%LOCATION%, C=%COUNTRY%"
if %errorlevel% neq 0 (
    echo 生成 Keystore 文件时出错！
    pause
    exit /b 1
)

rem 导出证书的摘要信息到文本文件
"%JDK_BIN_DIR%\keytool.exe" -list -v -keystore "%KEYSTORE_DIR%\%ALIAS%.keystore" -storepass %PASSWORD% | findstr "SHA1: SHA256:" > "%KEYSTORE_DIR%\%ALIAS%.txt"
if %errorlevel% neq 0 (
    echo 导出证书摘要信息到文本文件时出错！
    pause
    exit /b 1
)

echo 证书生成完成！Keystore 文件: %KEYSTORE_DIR%\%ALIAS%.keystore，证书摘要信息文件: %KEYSTORE_DIR%\%ALIAS%.txt
pause