当前位置：首页 > news >正文

win32汇编环境,网络编程入门之十六

news 2025/7/5 4:52:44

;win32汇编环境,网络编程入门之十六
;在这一教程里，学习一下，如何简单的大规模搜索可访问的域名，即搜索可用网址
;其基本原理是，通过组合不同的字符或数字，通过其返回的状态码来确定域名，如果返回值是200，则说明可访问HTTP网站，当然，返回值是0可能说明没有这个域名，也可能说明我们无法访问。
;不能通过IP地址的方式进行尝试，因为现在IP地址是稀缺资源，很多的时候，1个IP地址下面有大量的域名存在，比如很多网站都是在虚拟空间放着的。
;本示例从 www.abc0001.com 一直搜索到 www.abc1000.com 共1000个域名，看其返回值是不是200来判断这个域名是否能访问。
;另外，这里仅用编辑框显示信息，但编辑框显示的字符有限，所以本示例只搜索1000个网站试试。如果太多，比如10000个，可以尝试保存到文本文件里面去。

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.386
.model flat,stdcall
option casemap:none

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Include 文件定义
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
include windows.inc
include user32.inc
include kernel32.inc
include wininet.inc ;需要添加的wininet头文件

includelib user32.lib
includelib kernel32.lib
includelib wininet.lib ;需要添加的wininet库文件

; 自定义函数声明
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DlgProc proto :DWORD,:DWORD,:DWORD,:DWORD ;对话框窗口函数

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Equ 等值定义
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
MAINDIALOG equ 1
ICO_MAIN equ 1000 ;图标

ID_BUTTON01   equ 41
ID_EDIT01   equ 11
ID_EDIT02   equ 12
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 数据段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.data

szMsg db "提示",0
szErr db "错误",0
szFrm01 db "www.abc000%d.com",0
szFrm02 db "www.abc00%d.com",0
szFrm03 db "www.abc0%d.com",0
szRecCodeFrm db " 网站返回值是 %s",0

szEnter db 13,10,0 ;回车换行符

szAgent db "Microsoft Internet Explorer",0 ;骗网站说自已是IE浏览器
szHostName db "www.kepai2023.cn",0 ;要访问的主机域名
szUrlPath db "/",0 ;要访问的页面是主页
szVerb db "GET",0 ;GET方法访问
szAccept db "Accept: text/html",0 ;只接受text或html文件返回

.data?
hInstance HINSTANCE ?
hEdithwnd01 HWND ?
hEdithwnd02 HWND ?

hInternet dd ?
hHttpSession dd ?
hHttpRequest dd ?

szNewHostName db 128 dup (?) ;不同域名的字符串变量，须是全局变量
hAdd_1 dd ? ;用来产生1000个网站的数字

.const

; 代码段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.code
start:
invoke GetModuleHandle, NULL
mov hInstance,eax
invoke DialogBoxParam, hInstance, MAINDIALOG,NULL, addr DlgProc, NULL
invoke ExitProcess,eax
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;每调用本函数就生成新的域名，从 abc0001.com abc0002.com abc0003.com abc0004.com 直至 abc1000.com ，当然可以用不同的方式产生不同的域名
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_CreateHostName   proc
LOCAL @szBuffer[128]:byte
LOCAL @stCR:CHARRANGE

invoke   RtlZeroMemory,addr @szBuffer,sizeof @szBuffer
invoke   RtlZeroMemory,addr szNewHostName,sizeof szNewHostName

.if hAdd_1 < 10
   invoke wsprintf,addr @szBuffer,addr szFrm01,hAdd_1
.elseif hAdd_1 >= 10 && hAdd_1 < 100
invoke wsprintf,addr @szBuffer,addr szFrm02,hAdd_1
.elseif hAdd_1 >= 100 && hAdd_1 <= 1000
invoke wsprintf,addr @szBuffer,addr szFrm03,hAdd_1
.endif
invoke lstrcpy,addr szNewHostName,addr @szBuffer ;把生成的新网址保存到全局字符串变量 szNewHostName 里面去

inc hAdd_1

       ret

_CreateHostName   endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WorkThread   proc   _lParam
LOCAL @szBuffer[256]:byte
LOCAL @szRecBuffer[1024]:byte
LOCAL @stCR:CHARRANGE

LOCAL @szContentLength[128]:byte
LOCAL @Totallength

mov ebx,0
   .while TRUE
       .break .if ebx == 1001 ;循环1000次，即检测1000个网站
       invoke _CreateHostName ;获得新产生的域名，就是网址
       invoke InternetOpen,addr szAgent,INTERNET_OPEN_TYPE_DIRECT,NULL,NULL,0 ;初始化应用程序的 WinINet 函数的使用
   mov hInternet,eax

   invoke InternetConnect,hInternet,addr szNewHostName,80,NULL,NULL,INTERNET_SERVICE_HTTP,0,0 ;为给定站点打开文件传输协议（FTP）或 HTTP 会话,80是http的端口
   mov hHttpSession,eax
   .if eax == NULL
        invoke MessageBox,NULL,addr szErr,addr szMsg,MB_OK
   .endif

   invoke HttpOpenRequest,hHttpSession,addr szVerb,addr szUrlPath,NULL,addr szAccept,0,0,0 ;创建 HTTP 请求句柄
   mov hHttpRequest,eax

   invoke HttpSendRequest,hHttpRequest,NULL,0,NULL,0 ;将指定的请求发送到 HTTP 服务器
   mov @Totallength,128 ;注意这里要先赋值为缓冲区的字节大小，不能使用sizeof前面缓冲区的大小，因为它还要保存其它的值
   invoke HttpQueryInfo,hHttpRequest,HTTP_QUERY_STATUS_CODE,addr @szContentLength,addr @Totallength,NULL

   invoke RtlZeroMemory,addr @szBuffer,sizeof @szBuffer
   invoke wsprintf,addr @szRecBuffer,addr szRecCodeFrm,addr @szContentLength
   invoke lstrcat,addr @szBuffer,addr szNewHostName
   invoke lstrcat,addr @szBuffer,addr @szRecBuffer
   invoke GetWindowTextLength,hEdithwnd01
   mov @stCR.cpMin,eax
       mov @stCR.cpMax,eax

       invoke SendMessage,hEdithwnd01,EM_EXSETSEL,0,addr @stCR
   invoke SendMessage,hEdithwnd01,EM_REPLACESEL,FALSE,addr @szBuffer
   invoke SendMessage,hEdithwnd01,EM_REPLACESEL,FALSE,addr szEnter ;加上回车换行符

   invoke InternetCloseHandle,hHttpRequest ;反向清除各类HINTERNET 句柄，即先生成的后清除，后生成的先清除
        invoke InternetCloseHandle,hHttpSession
   invoke InternetCloseHandle,hInternet

       inc ebx
   .endw

ret

_WorkThread endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DlgProc proc hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
LOCAL   @stWsa:WSADATA

.if uMsg == WM_INITDIALOG
   invoke   LoadIcon,hInstance,ICO_MAIN
   invoke   SendMessage,hWnd,WM_SETICON,ICON_BIG,eax

invoke GetDlgItem,hWnd,ID_EDIT01
mov hEdithwnd01,eax
invoke GetDlgItem,hWnd,ID_EDIT02
mov hEdithwnd02,eax

mov hAdd_1,1 ;初始化为1，这个用于每次产生新域名时，用来给域名加1用
.elseif   uMsg ==   WM_COMMAND
           mov   ebx,wParam
       .if   bx ==   ID_BUTTON01
       invoke SendMessage,hEdithwnd01,WM_SETTEXT,0,0 ;清空编辑框
       invoke   CreateThread,NULL,0,offset _WorkThread,0,NULL,0 ;启动连接线程,用线程的原因是不让网络等待卡住主进程
           .endif
.elseif uMsg == WM_CLOSE
invoke InternetCloseHandle,hHttpRequest ;反向清除各类HINTERNET 句柄，即先生成的后清除，后生成的先清除
invoke InternetCloseHandle,hHttpSession
invoke InternetCloseHandle,hInternet
       invoke EndDialog,hWnd,NULL
.else
mov eax,FALSE
ret
.endif
mov eax,TRUE
ret
DlgProc endp

end start

;下面为rc文件内容
#include "resource.h" //提示缺少该文件，可以在资源里下载
//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
#define MAINDIALOG 1
#define ICO_MAIN 1000 //图标
#define ID_BUTTON01 41