汇编语言 第九章-转移指令的原理

操作符offset

介绍

操作符offset在汇编语言中是由编译器处理的符号，也就是伪指令。它的功能是取得标号的偏移地址。    

比如下面的程序：      

assume cs:codesg      

codeseg segment        

start:mov ax,offset start ; 相当于 mov ax,0。因为start的地址是cs：0，则偏移地址是0              

s:mov ax,offset s      ; 相当于mov ax,3，因为此时执行完上面的代码之后，偏移地址是3，在这段代码前标识了一个s标号，那么标号s的偏移地址也是3       

codesg ends      

end start

案例

有如下程序段，添写2条指令，使该程序在运行中将s处的一条指令复制到s0处。

assume cs:codesg
 codesg segment
   s: mov ax,bx              ;（nop的机器码占一个字节）
       mov si,offset s
       mov di,offset s0
       __________
       __________
 s0:  nop                       ;（nop的机器码占一个字节）
       nop
 codesg ends
ends

（1）s和s0处的指令所在的内存单元的地址是多少？               cs:offset s 和cs:offset s0。

（2）将s处的指令复制到s0处，就是将cs:offeet s 处的数据复制到cs:offset s0处；

（3）段地址已知在cs中，偏移地址offset s和offset s0已经送入si和di中；

（4）要复制的数据有多长？    mov ax,bx指令的长度为两个字节，即1个字。

jmp指令

介绍

jmp为无条件转移，可以只修改IP，也可以同时修改CS和IP；

jmp指令要给出两种信息：

转移的目的地址

转移的距离（段间转移、段内短转移，段内近转移）

jmp short 标号

介绍

格式：

jmp short 标号（转到标号处执行指令）        

这种格式的 jmp 指令实现的是段内短转移，它对IP的修改范围为 -128~127，也就是说，它向前转移时可以最多越过128个字节，向后转移可以最多越过127个字节。

举例

比如：程序9.1
assume cs:codesg
codesg segment
  start:mov ax,0
          jmp short s
          add ax,1
       s:inc ax
codesg ends
end start

上面的程序执行后， ax中的值为 1 ，因为执行  jmp short s 后 ，越过了add ax,1 ，IP 指向了标号 s处的 inc ax。也就是说，程序只进行了一次ax加1操作。

jmp short s 对应的机器指令

我们先看一下别的汇编指令和其对应的机器指令

汇编指令与机器码的对应示例 ：   

可以看到，在一般的汇编指令中，汇编指令中的idata（立即数），不论它是表示一个数据还是内存单元的偏移地址，都会在对应的机器指令中出现，因为CPU执行的是机器指令，它必须要处理这些数据或地址。

现在我们在Debug中将程序翻译成为机器码，看看结果

源代码：

比如：程序9.1
assume cs:codesg
codesg segment
  start:mov ax,0
          jmp short s
          add ax,1
       s:inc ax
codesg ends
end start

程序翻译成的机器码：

我们可以看到，在jmp 0008处，机器码是EB03，也就是说这个机器码中竟不包含转移的目的地址。 这意味着，CPU 在执行EB 03的时候，并不知道转移目的地址。

那么，CPU根据什么进行转移呢？

实际上，指令“jmp short 标号”的功能为(IP)=(IP)+8位位移。

（1）8位位移=“标号”处的地址-jmp指令后的第一个字节的地址；对应上面的代码就是标号处s的代码的地址076C：0008 减去 jmp指令后的第一个字节的地址，也就是076C：0005.

（2）short指明此处的位移为8位位移；

（3）8位位移的范围为-128~127，用补码表示   

 （4）8位位移由编译程序在编译时算出。

jmp near ptr 标号

与“jmp short 标号”功能相近，它实现的是段内近转移。

格式：    

jmp near ptr 标号

指令“jmp near ptr 标号”的功能为：     (IP)=(IP)+16位位移。

指令“jmp near ptr 标号”的说明：

（1）16位位移=“标号”处的地址-jmp指令后的第一个字节的地址；

（2）near ptr指明此处的位移为16位位移，进行的是段内近转移；

（3）16位位移的范围为    -32769~32767，用补码表示；

（4）16位位移由编译程序在编译时算出。

jmp far ptr 标号

前面讲的jmp指令，其对应的机器码中并没有转移的目的地址，而是相对于当前IP的转移位移。 指令 “jmp far ptr 标号”    实现的是段间转移，又称为远转移。

指令 “jmp far ptr 标号” 功能如下：

(CS)=标号所在段的段地址；

(IP)=标号所在段中的偏移地址。

far ptr指明了指令用标号的段地址和偏移地址修改CS和IP。

我们看下面的程序

 assume cs:codesg
           codesg segment
           start:mov ax,0
		         mov bx,0
                   jmp far ptr  s
                   db 256 dup (0)
               s: add ax,1
                   inc ax
           codesg ends
           end start

我们在Debug中将程序9.3翻译成为机器码，看到的结果如图：

如图中所示：    源程序中的db 256 dup (0)，被Debug解释为相应的若干条汇编指令 。这不是关键，

关键是，我们要注意一下jmp far ptr s所对应的机器码：EA 0B 01 BD 0B ，其中包含转移的目的地址。

“0B 01 BD 0B” 是目的地址在指令中的存储顺序，高地址的“BD 0B”是转移的段地址：0BBDH，低地址的“0B 01” 是偏移地址：010BH。

jmp word ptr 内存单元地址

功能：从内存单元地址处开始存放着一个字，是转移的目的偏移地址。    

内存单元地址可用寻址方式的任一格式给出。

示例：

mov ax,0123H
mov ds:[0],ax
jmp word ptr ds:[0]
执行后，(IP)=0123H

mov ax,0123H
mov [bx],ax
jmp word ptr [bx]
执行后，(IP)=0123H

jmp dword ptr 内存单元地址（段间转移）

功能：从内存单元地址处开始存放着两个字，高地址处的字是转移的目的段地址，低地址处是转移的目的偏移地址。         

(CS)=(内存单元地址+2)         

(IP)=(内存单元地址)    

内存单元地址可用寻址方式的任一格式给出

示例：

mov ax,0123H
mov ds:[0],ax
mov word ptr ds:[2],0
jmp dword ptr ds:[0]

执行后，
(CS)=0
(IP)=0123H
CS:IP 指向 0000：0123。





mov ax,0123H
mov [bx],ax
mov word ptr [bx+2],0
jmp dword ptr [bx]

执行后，
(CS)=0
(IP)=0123H
CS:IP 指向 0000：0123。

为什么分“段内”和“段间”？

这里的“段”是指段寄存器!!!

因为段寄存器不变：无论是近跳转还是短跳转，它们都不改变段寄存器（如CS、DS等）的值。这意味着跳转的目标地址仍然在当前段内，只是偏移地址发生了变化。

jcxz指令

jcxz指令为有条件转移指令，所有的有条件转移指令都是短转移，在对应的机器码中包含转移的位移，而不是目的地址。

对IP的修改范围都为-128~127。

指令格式：jcxz 标号      

（如果(cx)=0，则转移到标号处执行。）

jcxz 标号 指令操作：

当(cx)=0时，(IP)=(IP)+8位位移）

8位位移=“标号”处的地址-jcxz指令后的第一个字节的地址；

8位位移的范围为-128~127，用补码表示；

8位位移由编译程序在编译时算出。

当(cx)=0时，什么也不做（程序向下执行）

实战

答案：

检测点9.2

补全编程，利用jcxz指令，实现在内存2000H段中查找第一个值为0的字节，找到后，将它的偏移地址存储在dx中。

assume cs:code

code segment

 start: mov ax,2000h

        mov ds,ax

        mov bx,0

     s: mov ch,0   

        mov cl,[bx]

        jcxz ok        ;当cx=0时，CS:IP指向OK

        inc bx     

        jmp short s

    ok: mov dx,bx

        mov ax ,4c00h

        int 21h

code ends

end start

loop指令

loop指令为循环指令，所有的循环指令都是短转移，在对应的机器码中包含转移的位移，而不是目的地址。

对IP的修改范围都为-128~127。

指令格式：loop 标号     ((cx))=(cx)-1，如果(cx)≠0，转移到标号处执行。

loop 标号 指令操作：

（1）(cx)=(cx)-1;

（2）如果(cx)≠0，(IP)=(IP)+8位位移。 8位位移=“标号”处的地址-loop指令后的第一个字节的地址；

8位位移的范围为-128~127，用补码表示；

8位位移由编译程序在编译时算出。 当(cx)=0，什么也不做（程序向下执行）

实战

答案：

assume cs:code

code segment

start:  mov ax,2000h

        mov ds,ax

        mov bx,0

      s:mov cl,[bx]

        mov ch,0

        inc cx     

        inc bx

        loop s

     ok:dec bx

        mov dx,bx

        mov ax,4c00h

        int 21h

code ends

end start

根据位移进行转移的意义

前面我们讲到：    

 jmp short 标号      

jmp near ptr 标号    

 jcxz 标号      

loop 标号    

等几种汇编指令，它们对 IP的修改是根据转移目的地址和转移起始地址之间的位移来进行的。在它们对应的机器码中不包含转移的目的地址，而包含的是到目的地址的位移距离。

如果loop s的机器码中包含的是s的地址，则就对程序段在内存中的偏移地址有了严格的限制； 因为机器码中包含的是 s 的地址，如果 s 处的指令不在目的地址处，程序的执行就会出错。

而loop s的机器码中包含的是转移的位移，就不存在这个问题了； 因为，无论 s处的指令的实际地址是多少，loop指令的转移位移是不变的。

案例分析

分析下面的代码的执行顺序

assume cs:codesg
codesg segment

        mov ax,4c00h
        int 21h

start:  mov ax,0

s:      nop
        nop

        mov di,offset s
        mov si,offset s2
        mov ax,cs:[si]
        mov cs:[di],ax

s0:     jmp short s

s1:     mov ax,0
        int 21h
        mov ax,0

s2:     jmp short s1
        nop

codesg ends

end start

总结

8086CPU的转移指令分为以下几类：
    1.无条件跳转指令（如：jmp）
    2.条件跳转指令
    3.循环指令（如：loop）
    4.过程，就像C语言中的函数
    5.中断
9.1 操作符offset
    操作符offset在汇编语言中由编译器处理，它的功能是取标号的偏移地址
    如：s:mov ax,offset s
9.2 jmp指令
    1.无条件转移，可以只修改ip，也可以同时修改cs和ip
        1.【jmp 段地址:偏移地址】  可以用来同时修改CS和IP
            指令中的段地址修改CS
            偏移地址修改IP
            这种用法编译器不认识，只能做在debug中使用
        2.【jmp 某一合法的寄存器】   仅修改IP的内容
            比如：jmp ax 或者 jmp bx（类似于mov IP ax）
    2.jmp指令要给出两种信息：
        1.转移的目的地址
        2.转移的距离（段间转移、段内短转移、段内近转移）
9.3 依据位移进行转移的jmp指令
    1.jmp short 标号【转到标号处执行指令,段内短转移】
      此格式实现的是：段内短转移，它对ip的修改范围为-128~127
    2.也就是说，它向前转移时可以最多越过128个字节，负数使用补码表示
      向后转移可以最多越过127个字节
    3.CPU不需要目的地址就可以实现对ip的修改
        jmp指令的机器码中不包含目的地址，但是可以实现跳转
        实现的方式，是在原地址的基础上进行一个偏移量，即位移
    4.还有一种和指令“jmp short 标号”功能类似的指令格式：
        jmp near ptr 标号，它实现的是段内近转移 
        功能为：(ip)=(ip)+16位位移
        jmp short 标号是8位的位移，而jmp near ptr 标号是16位位移
9.4 转移的目的地址在指令中的jmp指令
    前面讲的jmp指令，其对应的机器码中并没有转移的目的地址，而是相对于当前ip的转移位移
    1.指令“jmp far ptr 标号”
        实现的是段间转移，又称为远转移,这时机器码中应该明确给出【段地址】
    2.指令“jmp far ptr 标号”功能如下：
        (CS)=标号所在段的段地址
        (IP)=标号所在段中的偏移地址
        far ptr 指明了指令用标号的段地址和偏移地址修改cs和ip
9.5 转移地址在寄存器中的jmp指令
    指令格式：jmp 16位寄存器
    功能：修改ip寄存器中的值，把16位寄存器中的值送入到ip寄存器中
9.6 转移地址在内存中的jmp指令
    转移地址在内存中的jmp指令有两种格式：
    1.jmp word ptr 内存单元地址（段内转移）
        功能：将内存中的那个字视为一个偏移地址，然后跳转到那个偏移地址
        与【jmp 寄存器】功能相似
        内存单元地址可用寻址方式的任意格式给出
    2.jmp dword ptr 内存单元地址（段间转移）
        (ip)=(内存单元地址)   ;双字中的低位字是给ip的
        (cs)=(内存单元地址+2) ;双字中的高位字是给cs的
        跟【jmp 段地址:偏移地址】功能类似
        内存单元地址可用寻址方式的任意格式给出
        **补充：不能直接向内存单元中加入立即数
            要通过寄存器，把立即数加进去
9.7 jcxz指令
    1.有条件跳转指令，所有的有条件跳转指令都是短转移
        对应的机器码中包含转移的位移，而不是目的地址。对ip的修改范围都为：-128~127
        **另一个有条件跳转指令【loop指令】
    2.指令格式：jcxz 标号
        如果（cx）=0，则跳转到标号处执行
    3.jcxz 标号 指令的操作：
        1.当(cx)=0时，(ip)=(ip)+8位位移
        2.当(cx)!=0时，什么也不做（程序继续向下执行）
9.8 loop指令
    1.循环指令，所有的循环指令都是短转移，在对应的机器码中包含转移的位移
    2.指令格式：loop 标号
    3.指令的内部操作
        1.cx=cx-1
        2.如果cx!=0，(ip)=(ip)+8位位移，跳转
        3.(cx)=0，什么也不做，程序向下执行
        cx用来控制循环的次数
9.9 根据位移进行转移的意义
    1.根据位移进行转移，这样设计，方便了程序段在内存中的浮动装配
        可以实现代码的复用
    2.如果在机器码中直接给出【段地址:偏移地址】，
        这段程序在内存中换一个位置，则会运行不正确
    3.段内近转移、段内短转移都是根据位移进行转移，一共有四种方式
        1.jmp short ptr 标号
        2.jmp near ptr 标号
        3.jcxz 标号
        4.loop 标号
9.10 编译器对转移位移超界的检测
    注意，根据位移进行转移的指令，他们的转移范围会受到限制
    如果在源程序中出现了转移范围超界的问题，在编译的时候，编译器将报错